//
//---------------------------- ImageJ Barrel/Pincushion Correction Macro Tool -------------------------------
                                      var barrelV=170430;
// ImageJ macro corrects images and stacks for barrel/pincushion distortion using SplineDeformationGenerator
// SplineDeformationGenerator only works on greyscale images; colour images will be converted to greyscale
//
// Install ImageJ with Java from https://imagej.nih.gov/ij/download.html and update it from its Help menu
// Copy this "Barrel Distortion.txt" file to your ImageJ\macros\toolsets folder and click Help/Refresh Menus
// Copy the jar file from "http://imagej.net/Spline_Deformation_Generator\" to ImageJ\Plugins & restart ImageJ
//
// (1) Click the >> icon in the ImageJ toolbar and select the Barrel Distortion tool
// (2) Right-click the Barrel Distortion tool icon that appears and set the K1 and K2 distortion parameters
// (3) Left-click  the Barrel Distortion tool icon to correct images and eventually save the corrected versions
// The K1/K2 parameters must be determined by trial and error by correcting the distorted image of a regular grid
// Try K1=0.06 K2=0.0 with the example image stack "http://neutronoptics.com/downloads/Bstack.tif"

// Email <alan.hewat@gmail.com> if you have questions or suggestions
//
	var K1  = call("ij.Prefs.get", "captureTool.K1","0.06");                        //K1 for lens correction
	var K2  = call("ij.Prefs.get", "captureTool.K2","0.0");                         //K2 for lens correction
	var Correction="";                                                              //Correction is plugin
	macro 'NeutronOptics Distortion (right click to set options, left click to execute) Action Tool - T0d18(Tgd18)T4h22+' //String defining the icon
{ 
    setBatchMode(true);
	List.setCommands;                                                               //Check if Spline Correction installed
	if (List.get("SplineDeformationGenerator ")!="")                                //Name of original spline correction
	   Correction="SplineDeformationGenerator ";                                    //Use original Spline Correction
	if (List.get("Spline Deformation Generator")!="")                               //Name of latest spline correction
	   Correction="Spline Deformation Generator";                                   //Use latest Spline Correction
	   if(Correction=="")                                                           //Spline correction not found
	   {showMessage("Please copy \"http://imagej.net/Spline_Deformation_Generator\" jar file to Plugins"); exit;}
	imageDir=getInfo("image.directory");                                            //Get the orig image directory
	if(imageDir=="") {run("Save"); imageDir=getInfo("image.directory");};           //Save the image if not saved
	fileName=getInfo("image.filename");                                             //Get the orig file name
	iExt=indexOf(fileName, ".")+1;                                                  //Get image file extension
	imageForm=substring(fileName, iExt);                                            //Determine image format
	File.makeDirectory(imageDir+"\\tifs");                                          //Make temporary tiffs dir 
	run("16-bit");                                                                  //Convert to greyscale
	saveAs("TIF",imageDir+"\\tifs\\temp.tif");                                      //Correction only works with TIF
	n=nSlices;                                                                      //Number of slices if a stack
	close("*");                                                                     //Close all images	
	for (i=1; i<n+1; i++) {                                                         //For every slice
	  open(imageDir+"\\tifs\\temp.tif",i);                                          //Re-display original image
	  saveAs("TIF",imageDir+"\\tifs\\tempo.tif");                                   //Save image as a temp TIF
	  run(Correction,                                                               //Correct for distortion
	      "-barrel "+imageDir+"\\tifs\\tempo.tif "+K1+" "+K2+" "+imageDir+"\\tifs\\temp"+i+".tif"); 
	  close();                                                                      //Close temp tempo file
	  File.delete(imageDir+"\\tifs\\tempo.tif");                                    //Delete tempo file
	  open(imageDir+"\\tifs\\temp"+i+".tif");                                       //Open corrected TIF file
	  run("16-bit");                                                                //Convert corrected TIF to 16-bits  
	  saveAs(imageDir+"\\tifs\\temp"+i+".tif");                                     //Save corrected image    
	}                                                                               //All corrected slices are open
	File.delete(imageDir+"\\tifs\\temp.tif");                                       //Delete the temp file
    if(n>1) run("Images to Stack", "name='Corrected-"+fileName+"' title=[] use keep");//Create stack with open slices
	close("temp*");                                                                 //Close all corrected slices
	if(n==1) open(imageDir+"\\tifs\\temp1.tif");                                    //Re-open single corrected image
	setBatchMode(false);                                                            //Show original & corrected images
	open(imageDir+fileName);                                                        //Re-display original image
	if(n==1) selectWindow("temp1.tif"); else selectWindow("Corrected-"+fileName);   //Select corrected image              
	for (i=1; i<n+1; i++) {File.delete(imageDir+"\\tifs\\temp"+i+".tif");};         //Delete all corrected slices
	File.delete(imageDir+"\\tifs");                                                 //Delete the tempory tiffs dir
	showMessageWithCancel("Save as "+imageForm+" file "+imageDir+fileName+" ?");    //Save corrected image in orig format
	saveAs(imageForm, imageDir+fileName);                                           //Save corrected image    
	close(fileName);                                                                //Close original image
	close("temp*");                                                                 //Close any temp images
	open(imageDir+fileName);                                                        //Re-display original image
	}

macro 'NeutronOptics Distortion (right click to set options, left click to execute) Action Tool Options'
{	
    Dialog.create("Barrel/Pincushion Distortion Corrections");
    Dialog.addMessage("Version "+barrelV);
    Dialog.addMessage("Parameters determined using grid");
    Dialog.addNumber("Barrel/Pincushion K1", K1,3,6,"(0.06)");
    Dialog.addNumber("Barrel/Pincushion K2", K2,3,6,"(0.00)");
    Dialog.show();
    K1= Dialog.getNumber();
    K2= Dialog.getNumber();
	call("ij.Prefs.set", "captureTool.K1",K1);
    call("ij.Prefs.set", "captureTool.K2",K2);
 }